home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zgelqf.f < prev    next >
Text File  |  1996-07-19  |  5KB  |  187 lines
  1.       SUBROUTINE ZGELQF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            INFO, LDA, LWORK, M, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  ZGELQF computes an LQ factorization of a complex M-by-N matrix A:
  19. *  A = L * Q.
  20. *
  21. *  Arguments
  22. *  =========
  23. *
  24. *  M       (input) INTEGER
  25. *          The number of rows of the matrix A.  M >= 0.
  26. *
  27. *  N       (input) INTEGER
  28. *          The number of columns of the matrix A.  N >= 0.
  29. *
  30. *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  31. *          On entry, the M-by-N matrix A.
  32. *          On exit, the elements on and below the diagonal of the array
  33. *          contain the m-by-min(m,n) lower trapezoidal matrix L (L is
  34. *          lower triangular if m <= n); the elements above the diagonal,
  35. *          with the array TAU, represent the unitary matrix Q as a
  36. *          product of elementary reflectors (see Further Details).
  37. *
  38. *  LDA     (input) INTEGER
  39. *          The leading dimension of the array A.  LDA >= max(1,M).
  40. *
  41. *  TAU     (output) COMPLEX*16 array, dimension (min(M,N))
  42. *          The scalar factors of the elementary reflectors (see Further
  43. *          Details).
  44. *
  45. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  46. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  47. *
  48. *  LWORK   (input) INTEGER
  49. *          The dimension of the array WORK.  LWORK >= max(1,M).
  50. *          For optimum performance LWORK >= M*NB, where NB is the
  51. *          optimal blocksize.
  52. *
  53. *  INFO    (output) INTEGER
  54. *          = 0:  successful exit
  55. *          < 0:  if INFO = -i, the i-th argument had an illegal value
  56. *
  57. *  Further Details
  58. *  ===============
  59. *
  60. *  The matrix Q is represented as a product of elementary reflectors
  61. *
  62. *     Q = H(k)' . . . H(2)' H(1)', where k = min(m,n).
  63. *
  64. *  Each H(i) has the form
  65. *
  66. *     H(i) = I - tau * v * v'
  67. *
  68. *  where tau is a complex scalar, and v is a complex vector with
  69. *  v(1:i-1) = 0 and v(i) = 1; conjg(v(i+1:n)) is stored on exit in
  70. *  A(i,i+1:n), and tau in TAU(i).
  71. *
  72. *  =====================================================================
  73. *
  74. *     .. Local Scalars ..
  75.       INTEGER            I, IB, IINFO, IWS, K, LDWORK, NB, NBMIN, NX
  76. *     ..
  77. *     .. External Subroutines ..
  78.       EXTERNAL           XERBLA, ZGELQ2, ZLARFB, ZLARFT
  79. *     ..
  80. *     .. Intrinsic Functions ..
  81.       INTRINSIC          MAX, MIN
  82. *     ..
  83. *     .. External Functions ..
  84.       INTEGER            ILAENV
  85.       EXTERNAL           ILAENV
  86. *     ..
  87. *     .. Executable Statements ..
  88. *
  89. *     Test the input arguments
  90. *
  91.       INFO = 0
  92.       IF( M.LT.0 ) THEN
  93.          INFO = -1
  94.       ELSE IF( N.LT.0 ) THEN
  95.          INFO = -2
  96.       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  97.          INFO = -4
  98.       ELSE IF( LWORK.LT.MAX( 1, M ) ) THEN
  99.          INFO = -7
  100.       END IF
  101.       IF( INFO.NE.0 ) THEN
  102.          CALL XERBLA( 'ZGELQF', -INFO )
  103.          RETURN
  104.       END IF
  105. *
  106. *     Quick return if possible
  107. *
  108.       K = MIN( M, N )
  109.       IF( K.EQ.0 ) THEN
  110.          WORK( 1 ) = 1
  111.          RETURN
  112.       END IF
  113. *
  114. *     Determine the block size.
  115. *
  116.       NB = ILAENV( 1, 'ZGELQF', ' ', M, N, -1, -1 )
  117.       NBMIN = 2
  118.       NX = 0
  119.       IWS = M
  120.       IF( NB.GT.1 .AND. NB.LT.K ) THEN
  121. *
  122. *        Determine when to cross over from blocked to unblocked code.
  123. *
  124.          NX = MAX( 0, ILAENV( 3, 'ZGELQF', ' ', M, N, -1, -1 ) )
  125.          IF( NX.LT.K ) THEN
  126. *
  127. *           Determine if workspace is large enough for blocked code.
  128. *
  129.             LDWORK = M
  130.             IWS = LDWORK*NB
  131.             IF( LWORK.LT.IWS ) THEN
  132. *
  133. *              Not enough workspace to use optimal NB:  reduce NB and
  134. *              determine the minimum value of NB.
  135. *
  136.                NB = LWORK / LDWORK
  137.                NBMIN = MAX( 2, ILAENV( 2, 'ZGELQF', ' ', M, N, -1,
  138.      $                 -1 ) )
  139.             END IF
  140.          END IF
  141.       END IF
  142. *
  143.       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
  144. *
  145. *        Use blocked code initially
  146. *
  147.          DO 10 I = 1, K - NX, NB
  148.             IB = MIN( K-I+1, NB )
  149. *
  150. *           Compute the LQ factorization of the current block
  151. *           A(i:i+ib-1,i:n)
  152. *
  153.             CALL ZGELQ2( IB, N-I+1, A( I, I ), LDA, TAU( I ), WORK,
  154.      $                   IINFO )
  155.             IF( I+IB.LE.M ) THEN
  156. *
  157. *              Form the triangular factor of the block reflector
  158. *              H = H(i) H(i+1) . . . H(i+ib-1)
  159. *
  160.                CALL ZLARFT( 'Forward', 'Rowwise', N-I+1, IB, A( I, I ),
  161.      $                      LDA, TAU( I ), WORK, LDWORK )
  162. *
  163. *              Apply H to A(i+ib:m,i:n) from the right
  164. *
  165.                CALL ZLARFB( 'Right', 'No transpose', 'Forward',
  166.      $                      'Rowwise', M-I-IB+1, N-I+1, IB, A( I, I ),
  167.      $                      LDA, WORK, LDWORK, A( I+IB, I ), LDA,
  168.      $                      WORK( IB+1 ), LDWORK )
  169.             END IF
  170.    10    CONTINUE
  171.       ELSE
  172.          I = 1
  173.       END IF
  174. *
  175. *     Use unblocked code to factor the last or only block.
  176. *
  177.       IF( I.LE.K )
  178.      $   CALL ZGELQ2( M-I+1, N-I+1, A( I, I ), LDA, TAU( I ), WORK,
  179.      $                IINFO )
  180. *
  181.       WORK( 1 ) = IWS
  182.       RETURN
  183. *
  184. *     End of ZGELQF
  185. *
  186.       END
  187.